Wikimedia Belgium Projects/ListeriaBot/Query

Wikimedia Belgium (WMBE) manages its projects through Wikidata.

When organising projects like edit-a-thons, it can be confusing, difficult, and laborious how to identify relevant pages.

Sometimes, it might be needed to have a list of item numbers for running e.g. a Pywikibot script.

Advantages

This project approach is data driven:

All data in one central place (Wikidata)
Easy to write queries and to automate data processing using Pywikibot
Enabling automated reporting
Linkable against all Wikimedia platforms (e.g. Wikipedia, Wikimedia Commons, including SDC)

Method

The following can be a typical flow for managing such project:

Create a Wikiproject in Wikidata
- Create claim (P31) (Q16695773) (Wikiproject)
- Create claim (P664) (organisator of Wikiproject item) (Q18398868) (Wikimedia Belgium)
Create or amend Wikidata items that are maintained by the project:
- Create claim (P6104) (maintained by) Wikiproject
Create a Wikipedia project page
Add a ListeriaBot subpage using the above Wikiproject item number, via a below query
Create new Wikipedia pages
Link the Wikipedia pages to the equivalent Wikidata item

Below you can find a list of example WMBE projects.

Queries

Wiki projects in Belgium

SELECT ?item ?linkcount WHERE {
  ?item wdt:P31 wd:Q16695773;
    wdt:P17 wd:Q31;
    wikibase:sitelinks ?linkcount.
}

Excecute: https://w.wiki/6YgN

Wiki projects organised by Wikimedia Belgium

This is a list of projects organised by Wikimedia Belgium:

SELECT ?wikiproject ?wikiprojectLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?wikiproject wdt:P31 wd:Q16695773.
  ?wikiproject wdt:P664 wd:Q18398868.
}

Excecute: https://w.wiki/$cN

It has been created by starting Wikidata Query, then entering the search items "wikiproject" and "WMBE" in the Filter section.

Wiki projects related to Wikimedia Belgium

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P31 wd:Q16695773.
  { ?item wdt:P664 wd:Q18398868. }
  UNION
  { ?item wdt:P710 wd:Q18398868. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Excecute: https://w.wiki/6YgB

Items linked to Wikimedia Belgium projects

This becomes a huge list...

SELECT DISTINCT ?item WHERE {
  ?item wdt:P6104 ?wikiproject.
  ?wikiproject wdt:P31 wd:Q16695773;
    wdt:P664 wd:Q18398868.
}

Excecute: https://w.wiki/5KRe

Missing language labels for items

SELECT distinct ?item WHERE {
  ?item wdt:P6104 ?wikiproject;
    wdt:P31 wd:Q5.
  ?wikiproject wdt:P31 wd:Q16695773;
    wdt:P664 wd:Q18398868.
  MINUS {
    ?item rdfs:label ?label.
    FILTER((LANG(?label)) = "da")
  }
}

Excecute: https://w.wiki/5nkB

The list of Q-numbers can be fed into a Pywikibot script to add the missing labels.